1с удалить записи регистра сведений с отбором по реквизиту - Контакты компаний и предприятий на Atlaso.ru

Программисту 1с в работе не редко нужно очистить регистр сведений от записей. В этой заметке разберу примеры очистки различных вариантов регистров сведений.

Регистр сведений – объект конфигурации, позволяющий хранить произвольные данные в разрезе нескольких измерений. Например, в регистре сведений можно хранить цены в разрезе номенклатуры и виде цен, или курсы валют в разрезе валюты.

Очистка регистра сведений без регистратора

Что бы удалить все записи из регистра достаточно написать две строчки кода.

Выбрать регистр сведений для удаления.
Создать набор записей.
Записать пустой набор записей.

НаборЗаписей		= РегистрыСведений.СтатусыЗаданий.СоздатьНаборЗаписей();
НаборЗаписей.Записать();

Удаление записей в независимом регистре сведений с отбором. В примере удаляются все записи из регистра сведений “СтатусыЗаданий” по определенной организации.

Считаем что в переменную Орг установлена нужная для очистки организация.
Создаем набор записей.
Устанавливаем отбор по организации.
Записываем пустой набор данных.

Орг = ...;

НаборЗаписей = РегистрыСведений.СтатусыЗаданий.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Организация.Установить(Орг);
НаборЗаписей.Записать();

Удаление записей из регистра сведений подчиненного регистратору

Для очистки регистра сведений подчиненного регистратору в отборе обязательно указывать регистратор, в остальном работает так же как удаление записей в регистре сведений с отбором.

ДокументРегистратор = Документы.УстановкаЦенНоменклатуы....

НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Регистратор.Установить(ДокументРегистратор);
НаборЗаписей.Записать();

Удаление записей из регистра сведений подчиненного регистратору с дополнительным отбором

Для удаления части записей из регистра сведений в пределах одного регистратора нужно сделать отбор по регистратору, а потом отобрать записи для удаления. Например если мы хотим удалить из регистра цены только по определенной номенклатуре. Важно помнить, что при перепроведении документа удаленные записи появятся снова.

В этом примере установив отбор по регистратору, я добавляю обход полученных записей и создаю список записей подходящих по условию, а после удаляю их из набора. Набор записывается уже без этих записей.

НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Регистратор.Установить(ДокументРегистратор); //обязательно для подчиненных регистров
НаборЗаписей.Прочитать();

спЗаписиКоторыеНадоУдалить = Новый СписокЗначений;
Для Каждого Запись Из НаборЗаписей Цикл
    Если [условие для удаления записи] Тогда
        спЗаписиКоторыеНадоУдалить.Добавить(Запись);
    КонецЕсли; //[условие]
КонецЦикла;

Для Каждого тЗапись Из спЗаписиКоторыеНадоУдалить Цикл
    НаборЗаписей.Удалить(тЗапись.Значение);
КонецЦикла;

НаборЗаписей.Записать();

Удаление записей из регистра с большим количеством записей

В больших высоконагруженных базах бывает необходимо удалить миллионы или даже десятки миллионов записей, очень часто перечисленные выше способы вылетают с ошибкой памяти или не могут выполнится по другим причинам.

В этом примере я выберу все записи которые нужно удалить запросом, а потом буду удалять по одной, это позволит не блокировать таблицу на долгое время и не потреблять много памяти за один раз.

Запрос = Новый Запрос("ВЫБРАТЬ
|	ЦеныНоменклатуры.Регистратор
|ИЗ
|	РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
|	ГДЕ Условие";

Выборка = Запрос.Выполнить().Выбрать();
	
Пока Выборка.Следующий() Цикл
	НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
	НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);
	НаборЗаписей.Записать();	
КонецЦикла;

Источник

Определяем вид изменяемого регистра сведений

Регистры сведений в зависимости от режима записи подразделяются на независимые и с подчинением регистратору. Для того чтобы выяснить, к какому виду относится регистр, откройте его свойства:

После того, как Вы выяснили вид регистра сведений — Вы можете выбрать вариант действий с регистром.

Удаляем записи в независимом регистре сведений

Для очистки записей с отбором Вам нужно проанализировать состав измерений регистра сведений. Задавая отбор по измерениям, Вы можете частично удалять данные в регистре сведений. К примеру, рассмотрим регистр сведений КурсыВалют. В этом регистре 2 измерения: Валюта и БазоваяВалюта:

Теперь давайте рассмотрим 2 способа очистки записей по определенной Валюте. Первый способ — использование объекта НаборЗаписей:

Процедура ОчиститьЗаписиВНезависимомРегистреСведенийСОтбором(Валюта, БазоваяВалюта)
	Набор = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();
	Набор.Отбор.Валюта.Установить(Валюта);
	Набор.Отбор.БазоваяВалюта.Установить(Валюта);
	Набор.Записать();
КонецПроцедуры

В этом примере мы создаем набор записей, устанавливаем для него отбор по измерениям, но записи в набор не добавляем. В результате при записи набора будет выполнена очистка записей по валютам, установленным в качестве отбора.

Второй способ — использование объекта МенеджерЗаписи:

Процедура ОчиститьЗаписиВНезависимомРегистреСведенийСОтбором(Валюта, БазоваяВалюта)
	Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи();
	Запись.Валюта = Валюта;
	Запись.БазоваяВалюта = БазоваяВалюта;
	Запись.Удалить();
КонецПроцедуры

Оба вариант удалят записи по валюте. При использовании второго варианта платформа будет конвертировать менеджер записи в набор записей.

Не забывайте про порядок измерений в регистре. К примеру, если задавать отбор только по измерению Валюта — будут удаляться все записи по этой валюте независимо от значений второго измерения (БазоваяВалюта). Таким образом Вы можете либо более детально удалять записи, устанавливая отбор по нескольким измерениям, либо делать более общее удаление с использованием отбора только по одному измерению.

Удаляем записи в регистре с подчинением регистратору

Все записи в таком регистре подчинены регистратору. Поэтому для удаления записей Вам нужно задавать отбор по регистратору. В качестве примера будем использовать регистр ЦеныНоменклатуры. Все записи этого регистра подчинены документам-регистраторам. Состав измерений регистра:

Теперь рассмотрим, как можно удалить все записи по определенному регистратору:

Процедура ОчиститьЗаписиВЗависимомРегистреСведений(Регистратор)
	Набор = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
	Набор.Отбор.Регистратор.Установить(Регистратор);
	Набор.Записать();
КонецПроцедуры

Приведенный выше пример очистит все записи по регистратору. Теперь давайте рассмотрим пример удаления записей с отбором — к примеру нам необходимо удалить записи по определенной номенклатуре:

Процедура ОчиститьЗаписиВЗависимомРегистреСведений(Регистратор, Номенклатура)
	Набор = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
	Набор.Отбор.Регистратор.Установить(Регистратор);
	Набор.Прочитать();
	Для Индекс = 1 - Набор.Количество() По 0 Цикл
		Запись = Набор[- Индекс];
		Если Запись.Номенклатура = Номенклатура Тогда
			Набор.Удалить(- Индекс);
		КонецЕсли;
	КонецЦикла;
	Набор.Записать();
КонецПроцедуры

Первым действием мы устанавливаем отбор по регистратору и считываем записи. Далее в обратном порядке обходим записи и удаляем только нужные записи. Таким образом можно выполнять «точечную» очистку регистра.

Полная очистка записей регистра сведений

Ниже приведен пример, который полностью очистит записи в регистре сведений:

Процедура ОчиститьЗаписиРегистраСведений()
	Набор = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();
	Набор.Записать();
КонецПроцедуры

В дополнение приведем пример работы нашей обработки по удалению записей в произвольных регистрах сведений, скачать которую Вы можете по этой ссылке.

Наши разработки:

Источник

1С 8.2 УП : Как удалить записи независимого регистра сведений с отбором по конкретной организации?

Переменная УдаляемаяОрганизация содержит соответствующую ссылку.
Тогда очистка регистра от удаляемых записей может быть произведена следующим образом:

Код 1C v 8.х

 НаборЗаписей = РегистрыСведений.ОбъектыСтроительстваОрганизаций.СоздатьНаборЗаписей();

НаборЗаписей.Отбор.Организация.Установить(УдаляемаяОрганизация);

НаборЗаписей.Записать();

Создаем переменную НаборЗаписей, устанавливаем для нее отбор по значению организации равный УдаляемаяОрганизация. Кстати, отбор набора записей регистра всегда может устанавливаться только на равенство.
Далее записываем полученный пустой набор записей с замещением.
В результате все записи, соответствовавшие отбору, будут замещены пустым набором записей.

Источник

Регистры сведений в 1С — это прикладные объекты конфигурации для хранения данных в структурированном виде (в разрезе измерений). Например, в регистре сведений можно хранить курсы валют в разрезе валют, цены номенклатуры в разрезе номенклатур, ФИО физических лиц в разрезе физических лиц и т.д.

При проектировании разработчик указывает необходимость хранения данных в разрезе времени и минимальную периодичность, с которой записи будут храниться в регистре:

Регистры сведений, для которых указана периодичность, называются периодическими.

Изменение данных в регистре может осуществляться как вручную, так и при помощи документов. Режим записи в регистр определяет разработчик на этапе проектирования:

Физически регистр сведений представляет собой таблицу, в которой хранятся следующие данные:

измерения — описывают разрезы, в которых хранится информация;
период — поле, используемое для разворота данных по времени. Поле добавляется автоматически при указании свойства «Периодичность», отличного от «Непериодический»;
регистратор — поле, используемое для хранения документа, с которым связана запись. Поле добавляется автоматически при указании свойства «Режим записи» в значение «Подчинение регистратору»;
ресурсы — непосредственно хранят информацию для комбинации измерений;
реквизиты — дополнительная произвольная информация, относящаяся к конкретной записи регистра.

Для всех регистров сведений обеспечивается контроль уникальности записей, т.е. в регистре не может быть двух одинаковых записей. Одинаковыми считаются записи, у которых совпадают значения измерений, период (если регистр периодический) и регистратор (если регистр подчинен регистратору).

Добавление записей

Программно добавить записи в регистр сведений можно при помощи:

объекта НаборЗаписей;
объекта МенеджерЗаписи.

Объект МенеджерЗаписи можно использовать только для работы с независимыми регистрами. Причем можно обрабатывать только одну запись. Объект предназначен в основном для интерактивной работы, но программно с ним также можно работать. На системном уровне МенеджерЗаписи использует объект НаборЗаписей.

Общая схема добавления записей в регистр сведений при помощи объекта НаборЗаписей выглядит так:

создание объекта НаборЗаписей;
наложение отборов на измерения, период (если регистр периодический) и регистратора (если регистр подчинен регистратору);
добавление и заполнение значений полей записей;
запись набора записей.

// Добавление записи в независимый непериодический регистр сведений
НаборЗаписей = РегистрыСведений.ВерсииПодсистем.СоздатьНаборЗаписей(); // Этап 1
НаборЗаписей.Отбор.ИмяПодсистемы.Установить(ИмяПодсистемы); // Этап 2
// Этап 3
НоваяЗапись = НаборЗаписей.Добавить();
НоваяЗапись.ИмяПодсистемы = ИмяПодсистемы;
НоваяЗапись.Версия = НомерВерсии;
НаборЗаписей.Записать(); // Этап 4

// Добавление записи в независимый периодический регистр сведений
НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); // Этап 1
// Этап 2
НаборЗаписей.Отбор.Валюта.Установить(Доллар);
НаборЗаписей.Отбор.Период.Установить(НачалоДня(ТекущаяДата()));
// Этап3
НоваяЗапись = НаборЗаписей.Добавить();
НоваяЗапись.Период = ТекущаяДата();
НоваяЗапись.Валюта = Доллар;
НоваяЗапись.Курс = 57.92;
НоваяЗапись.Кратность = 1;
НаборЗаписей.Записать(); // Этап 4

Общая схема добавления записей в регистр сведений при помощи объекта МенеджерЗаписи выглядит так:

создание объекта МенеджерЗаписи;
заполнение значений полей записи;
запись записи.

// Добавление записи в независимый непериодический регистр сведений
Запись = РегистрыСведений.ВерсииПодсистем.СоздатьМенеджерЗаписи(); // Этап 1
// Этап 2
Запись.ИмяПодсистемы = ИмяПодсистемы;
Запись.Версия = НомерВерсии;
Запись.Записать(); // Этап 3

// Добавление записи в независимый периодический регистр сведений
Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи(); // Этап 1
// Этап 2
Запись.Период = ТекущаяДата();
Запись.Валюта = Доллар;
Запись.Курс = 57.92;
Запись.Кратность = 1;
Запись.Записать(); // Этап 3

Изменение записей

Изменять существующие записи регистров сведений возможно при помощи объектов НаборЗаписей и МенеджерЗаписи. Ограничения объекта МенеджерЗаписи были описаны выше.

Общая схема редактирования записей регистров сведений:

создание объекта НаборЗаписей или МенеджерЗаписи;
наложение отборов;
чтение записей базы данных, соответствующих наложенным отборам;
редактирование прочитанных записей;
запись отредактированных записей.

// Редактирование записей с использованием объекта НаборЗаписей
НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); // Этап 1
// Этап 2
НаборЗаписей.Отбор.Период.Установить(ДатаКурса);
НаборЗаписей.Отбор.Валюта.Установить(Доллар);
НаборЗаписей.Прочитать(); // Этап 3
Для Каждого Запись Из НаборЗаписей Цикл 
     Запись.Курс = 57.84; // Этап 4
КонецЦикла;
НаборЗаписей.Записать(); // Этап 5

// Редактирование записей с использованием объекта МенеджерЗаписи
Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи(); // Этап 1
// Этап 2
Запись.Период = ДатаКурса;
Запись.Валюта = Доллар;
Запись.Прочитать(); // Этап 3
Если Запись.Выбран() Тогда // Проверка, что запись существует
    Запись.Курс = 57.92; // Этап 4
    Запись.Записать(); // Этап 5
КонецЕсли;

Чтение записей

Чтение информации из базы данных рекомендуется выполнять при помощи запросов. Данный способ обеспечивает гибкое применение отборов и группировок, а также возможность выбора записей из нескольких таблиц.

Запрос = Новый Запрос;
Запрос.Текст =
    "ВЫБРАТЬ
    |  КурсыВалют.Период,
    |  КурсыВалют.Валюта,
    |  КурсыВалют.Курс
    |ИЗ
    |  РегистрСведений.КурсыВалют КАК КурсыВалют";

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
    // обход результата выполнения запроса
КонецЦикла;

Для периодических регистров сведений есть возможность получить наиболее поздние записи, период которых меньше указанной даты — срез последних, и наиболее ранние записи, период которых больше указанной даты — срез первых. Для получения среза первых и среза последних запросом необходимо использовать одноименные виртуальные таблицы, в параметрах которых сразу можно задать дату среза и отборы. Отборы, если они необходимы, рекомендуется накладывать именно в параметрах виртуальных таблиц, т.к. это позволяет ускорить выполнение запроса.

// Получение записи, у которой валюта равна значению из переменной «ВыбраннаяВалюта»
// и период МЕНЬШЕ или равен значению из переменной «ВыбраннаяДата»
Запрос = Новый Запрос;
Запрос.Текст = 
    "ВЫБРАТЬ
    |  КурсыВалютСрезПоследних.Период,
    |  КурсыВалютСрезПоследних.Валюта,
    |  КурсыВалютСрезПоследних.Курс
    |ИЗ
    |  РегистрСведений.КурсыВалют.СрезПоследних(&Период, Валюта = &Валюта) КАК КурсыВалютСрезПоследних";

Запрос.УстановитьПараметр("Валюта", ВыбраннаяВалюта);
Запрос.УстановитьПараметр("Период", ВыбраннаяДата);

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
    // обход результата выполнения запроса
КонецЦикла;

// Получение записи, у которой валюта равна значению из переменной «ВыбраннаяВалюта»
// и период БОЛЬШЕ или равен значению из переменной «ВыбраннаяДата»
Запрос = Новый Запрос;
Запрос.Текст = 
    "ВЫБРАТЬ
    |  КурсыВалютСрезПервых.Период,
    |  КурсыВалютСрезПервых.Валюта,
    |  КурсыВалютСрезПервых.Курс
    |ИЗ
    |  РегистрСведений.КурсыВалют.СрезПервых(&Период, Валюта = &Валюта) КАК КурсыВалютСрезПервых";

Запрос.УстановитьПараметр("Валюта", ВыбраннаяВалюта);
Запрос.УстановитьПараметр("Период", ВыбраннаяДата);

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
    // обход результата выполнения запроса
КонецЦикла;

Кроме чтения запросом возможно использование методов объектной модели.

Для непериодических регистров сведений:

Выбрать(Отбор, Порядок) — выбирает записи с указанным отбором;
ВыбратьПоРегистратору(Регистратор) — выбирает все записи указанного регистратора;
Получить(Отбор) — получает ресурсы записи с отбором по всем измерениям.

Для периодических регистров сведений:

Выбрать(НачалоИнтервала, КонецИнтервала, Отбор, Порядок) — выбирает записи с указанным отбором, у которых период находится между НачалоИнтервала и КонецИнтервала;
ВыбратьПоРегистратору(Регистратор) — выбирает все записи указанного регистратора;
Получить(Период, Отбор) — получает ресурсы записи с отбором по всем измерениям и периоду;
ПолучитьПервое(НачалоПериода, Отбор) — получает ресурсы наиболее ранней записи, соответствующей указанным периоду и отбору;
ПолучитьПоследнее(КонецПериода, Отбор) — получает ресурсы наиболее поздней записи, соответствующей указанным периоду и отбору;
СрезПервых(НачалоПериода, Отбор) — получает таблицу наиболее ранних записей, соответствующую указанным периоду и отбору;
СрезПоследних(КонецПериода, Отбор) — получает таблицу наиболее поздних записей, соответствующую указанным периоду и отбору.

Удаление записей

Для удаления записи (записей) в независимом регистре сведений необходимо:

создать набор записей;

наложить требуемые отборы на измерения и период (если регистр периодический);

записать набор записей без предварительного чтения.

НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();

НаборЗаписей.Отбор.Валюта.Установить(Доллар);
НаборЗаписей.Отбор.Период.Установить(НачалоДня(ТекущаяДата()));

НаборЗаписей.Записать();

Для удаления записей в подчиненном регистре сведений необходимо:

создать набор записей;
наложить отбор на регистратора;
записать набор записей без предварительного чтения.

НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Регистратор.Установить(СсылкаНаДокументРегистратор);
НаборЗаписей.Записать();

Очистка регистра сведений

Для удаления всех записей в независимом регистре сведений достаточно записать набор записей этого регистра без установки отборов:

НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); 
НаборЗаписей.Записать();

Запись в регистр сведений, подчиненный регистратору, возможна только при установке отбора по регистратору, поэтому для очистки таких регистров необходимо:

получить перечень ссылок всех регистраторов регистра сведений;
последовательно записать пустой набор записей с отбором по регистраторам из первого пункта.

Запрос = Новый Запрос(
    "ВЫБРАТЬ
    | ЦеныНоменклатуры.Регистратор
    |ИЗ
    | РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры"
);

Выборка = Запрос.Выполнить().Выбрать();

НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
Пока Выборка.Следующий() Цикл 
     НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);
     НаборЗаписей.Записать();
КонецЦикла;

Источник

АКТУАЛЬНЫЕ РЕЛИЗЫ 1С
ПРИМЕРЫ КОДА НА ПЛАТФОРМЕ 1С

Работа с регистрами сведений в 1С 8.x

Как добавить запись в непериодический независимый регистр сведений?
Как считать содержимое непериодического независимого регистра сведений «СобственныеКонтрагенты»?
Как удалить все записи из независимого регистра сведений?
Как удалить записи независимого регистра сведений с отбором по конкретной организации?
Как добавить запись в периодический независимый регистр сведений?
Как прочитать (изменить) записи в периодическом независимом регистре сведений?
Как удалить записи в периодическом независимом регистре сведений?
Как в периодическом независимом регистре сведений «КурсыВалют» удалить все записи по валютам с наименованиями «EUR» и «USD», период которых меньше 01 января 2005 года?
Как прочитать данные, актуальные на определенную дату, из регистра сведений «Курсы валют» с отбором по нескольким валютам (отбор по измерениям)?
Как поменять период у записей периодического независимого регистра, соответствующих ряду условий?
Как «сделать периодическим» реквизит уже заполненного справочника?
Как добавить записи в регистр сведений, подчиненный регистратору?
Как прочитать (изменить) записи в регистре сведений, подчиненном регистратору?
Как удалить записи из регистра сведений, подчиненного регистратору?

Как добавить запись в непериодический независимый регистр сведений?


НаборЗаписей = РегистрыСведений.ЗначенияСвойств.СоздатьНаборЗаписей(); 

НаборЗаписей.Отбор.Номенклатура.Установить(ТекущаяНоменклатура); 
НаборЗаписей.Отбор.Свойство.Установить(ТекущееСвойство); 

НоваяЗапись = НаборЗаписей.Добавить(); 
НоваяЗапись. Номенклатура = ТекущаяНоменклатура; 
НоваяЗапись.Свойство = ТекущееСвойство; 
НоваяЗапись.Значение = ТекущееЗначение; 

НаборЗаписей.Записать();

Как считать содержимое непериодического независимого регистра сведений «СобственныеКонтрагенты»?


НаборЗаписей = РегистрыСведений.СобственныеКонтрагенты.СоздатьНаборЗаписей(); 
НаборЗаписей.Прочитать(); 

// Перебрать записи в цикле… 
Для Каждого Запись из НаборЗаписей Цикл 
	РегистрКонтрагент = Запись.Контрагент; 
	РегистрВидСвязи = Запись.ВидСвязи; 
	РегистрОбъект = Запись.Объект; 
КонецЦикла; 

// … или выгрузить записи в таблицу значений. 
ТаблицаЗаписей = НаборЗаписей.Выгрузить(); 


ВЫБРАТЬ 
	* 
ИЗ 
	РегистрыСведений.СобственныеКонтрагенты

Как удалить все записи из независимого регистра сведений?


НаборЗаписей = РегистрыСведений.ТорговоеОборудование.СоздатьНаборЗаписей(); 
НаборЗаписей.Записать();

Как удалить записи независимого регистра сведений с отбором по конкретной организации?


НаборЗаписей = РегистрыСведений.ОбъектыСтроительстваОрганизаций.СоздатьНаборЗаписей(); 
НаборЗаписей.Отбор.Организация.Установить(УдаляемаяОрганизация); 
НаборЗаписей.Записать();

Как добавить запись в периодический независимый регистр сведений?


НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); 

НаборЗаписей.Отбор.Валюта.Установить(ТекущаяВалюта); 
НаборЗаписей.Отбор.Период.Установить(ТекущаяДата); 

НовЗапись = НаборЗаписей.Добавить(); 
НовЗапись.Валюта = ТекущаяВалюта; 
НовЗапись.Период = ТекущаяДата; 
НовЗапись.Курс = ТекущийКурс; 
НовЗапись.Кратность = ТекущаяКратность; 

НаборЗаписей.Записать(Истина);

Как прочитать (изменить) записи в периодическом независимом регистре сведений?


НаборЗаписей = РегистрыСведений.Валюты.СоздатьНаборЗаписей(); 
НаборЗаписей.Отбор.Период.Установить(ДатаЗаписи); 

НаборЗаписей.Прочитать(); 

Для Каждого Запись Из НаборЗаписей Цикл 
	// Чтение и сообщение данных полей записи. 
	Сообщить(Строка(Запись.Период) + " " + Строка(Запись.Валюта) + " " + Строка(Запись.Курс)); 
	// Изменение данных полей записи. 
	Запись.Курс = 0; 
КонецЦикла; 

НаборЗаписей.Записать();

Как удалить записи в периодическом независимом регистре сведений?


НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); 
НаборЗаписей.Записать();

Как в периодическом независимом регистре сведений «КурсыВалют» удалить все записи по валютам с наименованиями «EUR» и «USD», период которых меньше 01 января 2005 года?


Запрос = Новый Запрос; 
Запрос.Текст = "ВЫБРАТЬ 
	|	* 
	|ИЗ 
	|	РегистрСведений.КурсыВалют КАК КурсыВалют 
	|ГДЕ 
	|	(КурсыВалют.Период >= ДАТАВРЕМЯ(2005, 1, 1) 
	|	ИЛИ 
	|	НЕ(КурсыВалют.Валюта.Наименование ПОДОБНО ""USD"") 
	|	И 
	|	НЕ(КурсыВалют.Валюта.Наименование ПОДОБНО ""EUR""))"; 


ТаблицаОставляемыхЗаписей = Запрос.Выполнить().Выгрузить(); 

НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); 
НаборЗаписей.Загрузить(ТаблицаОставляемыхЗаписей); 
НаборЗаписей.Записать();

Как прочитать данные, актуальные на определенную дату, из регистра сведений «Курсы валют» с отбором по нескольким валютам (отбор по измерениям)?


Запрос = Новый Запрос; 
МассивВалют = Новый Массив; 
МассивВалют.Добавить(Валюта1); 
МассивВалют.Добавить(Валюта2); 

Запрос.УстановитьПараметр("МассивВалют", МассивВалют); 
Запрос.УстановитьПараметр("ДатаПолучения", ДатаПолучения); 

Запрос.Текст = " 
	|ВЫБРАТЬ 
	|	ВалютыСрезПоследних.Валюта, 
	|	ВалютыСрезПоследних.Курс 
	|ИЗ 
	|	РегистрСведений.КурсыВалют.СрезПоследних(&ДатаПолучения, Валюта В (&МассивВалют)) КАК ВалютыСрезПоследних"; 

ТаблицаКурсов = Запрос.Выполнить().Выгрузить();

Как поменять период у записей периодического независимого регистра, соответствующих ряду условий?


Процедура ЗаменаПериода() 

	Запрос = Новый Запрос; 
	Запрос.Текст = "ВЫБРАТЬ 
	|	ОтветственныеЛицаОрганизации.Период, 
	|	ОтветственныеЛицаОрганизации.СтруктурнаяЕдиница, 
	|	ОтветственныеЛицаОрганизации.ОтветственноеЛицо 
	|ИЗ 
	|	РегистрСведений.ОтветственныеЛицаОрганизации КАК ОтветственныеЛицаОрганизации 
	|ГДЕ 
	|	ОтветственныеЛицаОрганизации.Период <= ДАТАВРЕМЯ(2005, 1, 1) 
	|	И 
	|	ОтветственныеЛицаОрганизации.СтруктурнаяЕдиница.Наименование | ПОДОБНО "Групп-Трейдинг" 
	|	И 
	|	(ОтветственныеЛицаОрганизации.Должность.Наименование ЕСТЬ NULL 
	|		ИЛИ 
	|		НЕ(ОтветственныеЛицаОрганизации.Должность.Наименование | ПОДОБНО "Продавец" 
	|			ИЛИ 
	|			ОтветственныеЛицаОрганизации.Должность.Наименование | ПОДОБНО "Кладовщик"))"; 

	Результат = Запрос.Выполнить(); 
	Выборка = Результат.Выбрать(); 

	Запись = РегистрыСведений.ОтветственныеЛицаОрганизации.СоздатьМенеджерЗаписи(); 

	Пока Выборка.Следующий() Цикл 
		Запись.Период = Выборка.Период; 
		Запись.СтруктурнаяЕдиница = Выборка.СтруктурнаяЕдиница; 
		Запись.ОтветственноеЛицо = Выборка.ОтветственноеЛицо;

		Запись.Прочитать(); 

		Если Запись.Выбран() Тогда 
			Запись.Период = Дата(2004, 1, 1); 
			Запись.Записать(); 
		КонецЕсли; 
	КонецЦикла; 

КонецПроцедуры;

Как «сделать периодическим» реквизит уже заполненного справочника?


Запрос = Новый Запрос; 
Запрос.Текст = "ВЫБРАТЬ 
	|	&ДатаУстановки КАК Период, 
	|	Проекты.Ссылка КАК Проект, 
	|	Проекты.Ответственный 
	|ИЗ 
	|	Справочник.Проекты КАК Проекты 
	|ГДЕ 
	|	(НЕ(Проекты.ЭтоГруппа)) И (НЕ(Проекты.Ответственный = &Ответственный))"; 

Запрос.УстановитьПараметр("Ответственный", Справочники.Пользователи.ПустаяСсылка()); 
Запрос.УстановитьПараметр("ДатаУстановки", Дата(2000,1,1)); 

ТаблицаРезультат = Запрос.Выполнить().Выгрузить(); 

НаборЗаписей = РегистрыСведений.ЗакреплениеПроектов.СоздатьНаборЗаписей(); 
НаборЗаписей.Загрузить(ТаблицаРезультат); 
НаборЗаписей.Записать();

Как добавить записи в регистр сведений, подчиненный регистратору?


НаборЗаписей = РегистрыСведений.ЛимитыВозвратнойТары.СоздатьНаборЗаписей(); 
НаборЗаписей.Отбор.Регистратор.Установить(ВыбранныйРегистратор); 
НоваяЗапись = НаборЗаписей.Добавить(); 
НоваяЗапись.Период = ВыбранныйРегистратор.Дата; 
НоваяЗапись.Номенклатура = ВыбраннаяНоменклатура; 
НоваяЗапись.ДоговорКонтрагента = ВыбранныйДоговор; 
НоваяЗапись.ЛимитПоставщика = 50; 
НаборЗаписей.Записать(); 


НаборЗаписей = РегистрыСведений.ЛимитыВозвратнойТары.СоздатьНаборЗаписей(); 
НаборЗаписей.Отбор.Регистратор.Установить(ВыбранныйРегистратор); 
НоваяЗапись = НаборЗаписей.Добавить(); 
НоваяЗапись.Период = ВыбранныйРегистратор.Дата; 
НоваяЗапись.Номенклатура = ВыбраннаяНоменклатура; 
НоваяЗапись.ДоговорКонтрагента = ВыбранныйДоговор; 
НоваяЗапись.ЛимитПокупателю = 25; 
НаборЗаписей.Записать(Ложь);

Как прочитать (изменить) записи в регистре сведений, подчиненном регистратору?


НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей(); 
НаборЗаписей.Отбор.Регистратор.Установить(ВыбранныйРегистратор); 
НаборЗаписей.Прочитать(); 
Для Каждого Запись Из НаборЗаписей Цикл 
	// Чтение и сообщение данных полей записи. 
	Сообщить(Строка(Запись.Период) + " " + Строка(Запись.ТипЦен) +" "+ Строка(Запись.Номенклатура) + 
	" " + Строка(Запись.Цена) + " " + Строка(Запись.ПроцентСкидкиНаценки)); 
	// Изменение данных полей записи. 
	Запись.ПроцентСкидкиНаценки = 0; 
КонецЦикла; 
НаборЗаписей.Записать();

Как удалить записи из регистра сведений, подчиненного регистратору?


Запрос = Новый Запрос; 
Запрос.Текст = " 
	|	ВЫБРАТЬ 
	|	ЦеныНоменклатурыКонтрагентов.Регистратор 
	|ИЗ 
	|	РегистрСведений.ЦеныНоменклатурыКонтрагентов КАК ЦеныНоменклатурыКонтрагентов"; 

Результат = Запрос.Выполнить(); 
Выборка = Результат.Выбрать(); 

НаборЗаписей = РегистрыСведений.ЦеныНоменклатурыКонтрагентов.СоздатьНаборЗаписей(); 
Пока Выборка.Следующий() Цикл 
	НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор); 
	НаборЗаписей.Записать(); 
КонецЦикла;

Задайте вопрос программисту 1С

Источник

Как удалить запись в независимом регистре сведений

Lenka_Boo

18.08.10 — 10:14

8.2 Комплексная автоматизация 1.0.9.1

Надо удалить записи В ИсторияКонтактныхЛицКонтрагентов.

с отбором по контрагенту(это реквизит).

Делаю

ИсторияКЛ = РегистрыСведений.ИсторияКонтактныхЛицКонтрагентов.СоздатьМенеджерЗаписи();

ИсторияКЛ.Контрагент = КонтрагентВыб;

ИсторияКЛ.Период = ТекущаяДата();

ИсторияКЛ.Прочитать();

//ИсторияКЛ.Удалить();

ИсторияКЛ.Записать();

Если делаю «Удалить», то ошибок нет ,но ничего не удаляет.

Если делаю «Записать», то ошибка:»Запись не верна! Период не может быть пустым!…»

Elena_KR

1 — 18.08.10 — 10:16

создать набор записей , отобрать по контрагенту, потом очистить и записать вновь

Elena_KR

2 — 18.08.10 — 10:17

записать(истина)

IronDemon

3 — 18.08.10 — 10:19

НаборЗаписей = РегистрыСведений.ИсторияКонтактныхЛицКонтрагентов.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Контрагент.Установить(Контрагент);
НаборЗаписей.Отбор.Период.Установить(ТекущаяДата());
НаборЗаписей.Записать();

artems

4 — 18.08.10 — 10:21

А зачем отбор по периоду ставить, вроде надо все записи по контрагенту грохнуть?

Lenka_Boo

5 — 18.08.10 — 10:24

(1),(3) Пробовала. Но отбор по контрагенту не катит, потому что это реквизит а не измерение.

(4) Подставила, думала ругаться перестанет. Не помогло.

Elena_KR

6 — 18.08.10 — 10:27

контактноелицо заполнено?

Elena_KR

7 — 18.08.10 — 10:31

сначала запрос к регистру ИсторияКонтактныхЛицКонтрагентов с отбором по контрагенту, потом в выборке к каждой записи:

НаборЗаписей = РегистрыСведений.ИсторияКонтактныхЛицКонтрагентов.СоздатьНаборЗаписей();

НаборЗаписей.Отбор.КонтактноеЛицоКонтрагента.Установить(ВЫборка.КонтактноеЛицоКонтрагента);

НаборЗаписей.Отбор.КонтактноеЛицо.Установить(ВЫборка.КонтактноеЛицо);

НаборЗаписей.Очистить();

НаборЗаписей.Записать(Истина);

stangen

8 — 18.08.10 — 10:33

Запрос = Новый Запрос(«ВЫБРАТЬ
| ИсторияКонтактныхЛицКонтрагентов.Период,
| ИсторияКонтактныхЛицКонтрагентов.Измерение1,
| ИсторияКонтактныхЛицКонтрагентов.Измерение2,
| ……
| ИсторияКонтактныхЛицКонтрагентов.ИзмерениеN
|ИЗ
| РегистрСведений.ИсторияКонтактныхЛицКонтрагентов КАК ИсторияКонтактныхЛицКонтрагентов
|ГДЕ
| ИсторияКонтактныхЛицКонтрагентов.МойРеквизит = &МойРеквизит»
Запрос.УстановитьПараметр(«МойРеквизит»,МойРеквизит);
Выборка=Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
НаборЗаписей = РегистрыСведений.ИсторияКонтактныхЛицКонтрагентов.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Период.Установить(Выборка.Период);
НаборЗаписей.Отбор.Измерение1.Установить(Выборка.Измерение1);
НаборЗаписей.Отбор.Измерение2.Установить(Выборка.Измерение2);
…….
НаборЗаписей.Отбор.ИзмерениеN.Установить(Выборка.ИзмерениеN);
НаборЗаписей.Прочитать();
НаборЗаписей.Очистить();
НаборЗаписей.Записать();
КонецЦикла;

Kashemir

9 — 18.08.10 — 10:44

В качестве примера http://infostart.ru/public/74068/

Поручик

10 — 18.08.10 — 11:28

Ещё пример, которым сам пользуюсь с начала релиза

http://infostart.ru/public/22108/

Lenka_Boo

11 — 24.08.10 — 12:57

Спасибо всем участвующим и сочуствующем!
С задачей справилась, хотя тайно надеялась избежать зигзагов с запросами и измерениями.

Программист всегда исправляет последнюю ошибку.

Источник

Переменная УдаляемаяОрганизация содержит соответствующую ссылку.

Тогда очистка регистра от удаляемых записей может быть произведена следующим образом:

Код 1C v 8.х

 НаборЗаписей = РегистрыСведений.ОбъектыСтроительстваОрганизаций.СоздатьНаборЗаписей();
      

    НаборЗаписей.Отбор.Организация.Установить(УдаляемаяОрганизация);
      

    НаборЗаписей.Записать();

Создаем переменную НаборЗаписей, устанавливаем для нее отбор по значению организации равный УдаляемаяОрганизация. Кстати, отбор набора записей регистра всегда может устанавливаться только на равенство.

Далее записываем полученный пустой набор записей с замещением.

В результате все записи, соответствовавшие отбору, будут замещены пустым набором записей.

Информация взята с сайта http://helpf.pro